home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 7
/
FM Towns Free Software Collection 7.iso
/
t_os
/
f_list
/
f_list.bas
< prev
next >
Wrap
BASIC Source File
|
1993-11-30
|
16KB
|
477 lines
1000 '1992/06/23 File Name Lister by 尋燐・ルナ
1010 '1992/12/23 完成バージョン V2.04
1020 '1993/07/28 最新バージョン V2.05
1030 '1991/OH!FM TOWNS 新創刊 NO.1 p160 DIR.REX 伊藤哲史作 使用
1040 CLEAR ,,,,512
1050 DEFSTR A
1060 :
1070 GOSUB *初期化
1080 GOSUB *マシン語
1090 GOSUB *項目設定
1100 *MLOOP
1110 GOSUB *初期化2
1120 GOSUB *画面
1130 GOSUB *入力
1140 GOSUB *入力変換
1150 GOSUB *WINDO2
1160 I=14 :GOSUB *W2
1170 OPEN "O",#1,OF_N$
1180 GOSUB *MAIN
1190 CLOSE
1200 I=15 :GOSUB *W2
1210 :A=INPUT$(1)
1220 :IF A="R" OR A="r" THEN *MLOOP
1230 *終了
1240 SYSTEM
1250 :
1260 '----SUB----
1270 *初期化
1280 DEF FNFILE$(F$)=F$+CHR$(0)+STRING$(18-LEN(F$),"a")
1290 DMAX=9 :'##ディレクトリの最大深さ-1
1300 DIM F_N$(DMAX,400) :'##深さ別のDIR名LIST
1310 DIM C_N(DMAX) :'##各深さのDIRの位置
1320 RETURN
1330 :
1340 *初期化2
1350 FCT=0 :FCT1=0:FCT2=0 :DIRC=0
1360 '該当F数:総F数 :特殊F数:総DIR数
1370 DIR=0 :PASS$="\"
1380 'DIRの深さ:パス
1390 F$="" :'##ファイル名のワーク
1400 S=0 :'##1=DIR検索 / 0=ファイル検索
1410 RETURN
1420 :
1430 *項目設定
1440 'ウインド1
1450 W1C=13 :'##ウインド1の最大項目数
1460 DIM AW1(W1C) :'##項目名
1470 DIM SW1(W1C) :'##設定1
1480 DIM AW11(W1C):'##設定2
1490 RESTORE *設定DATA :FOR I=0 TO W1C :READ AW1(I),SW1(I),AW11(I) :NEXT
1500 'ウインド2
1510 DIM AH(W1C+2) :'##HELPメッセージ
1520 RESTORE *HDATA :FOR I=0 TO W1C+2 :READ AH(I) :NEXT
1530 RETURN
1540 :
1550 *マシン語
1560 LOADM "DIR.REX",0
1570 MC1&=0 :MC2&=&HBB :'##マシン語コールアドレス(1,2)
1580 FLAG&=1
1590 RETURN
1600 :
1610 '--------
1620 *画面
1630 SCREEN@ 0 :CLS :WIDTH 80,20
1640 PALETTE 9,[100,100,120]
1650 PALETTE 10,[180,180,180]
1660 PALETTE 11,[0,0,120]
1670 LINE (0,0)-(639,479),PSET,%9,BF
1680 SYMBOL (30,10),"ファイル リスター",2,1,6,,,15
1690 SYMBOL (170,4),"N",1,1,5,,,7 :SYMBOL (180,9),"A",1,1,5,,,7
1700 SYMBOL (190,14),"M",1,1,5,,,7 :SYMBOL (200,19),"E",1,1,5,,,7
1710 SYMBOL (350,10),"V2.05",1,1,6,,,1,2
1720 SYMBOL (450,10),"HI-CCC",1,1,4,,,7
1730 SYMBOL (450,30),"製作者: 尋燐・ルナ",1,1,4,,,1
1740 LINE (35,40)-(435,40),PSET,%11
1750 CONNECT (435,5)-(405,60)-(620,60)-(610,50)-(610,70),%11
1760 GOSUB *WIND1
1770 X0=400 :Y0=105 :X1=600 :Y1=244 :GOSUB *ウインド
1780 COLOR 4 :LOCATE 57,4 :PRINT "メッセージ"
1790 X0=400 :Y0=298 :X1=600 :Y1=455 :GOSUB *ウインド
1800 COLOR 4 :LOCATE 57,12 :PRINT "処 理 経 過"
1810 COLOR 5 :LOCATE 51,13 :PRINT "該当File数 = ";FCT
1820 LOCATE 51,14 :PRINT "総ファイル数 = ";FCT1
1830 LOCATE 51,15 :PRINT "総DIR数 = ";DIRC
1840 LOCATE 51,16 :PRINT "特殊File数 = ";FCT2
1850 LOCATE 51,17 :PRINT "PASS [ 1 2 ]"
1860 LOCATE 51,18 :PRINT "DIRの深さ :"
1870 RETURN
1880 :
1890 *ウインド
1900 CONNECT (X0,Y1)-(X0,Y0)-(X1,Y0),%10
1910 CONNECT (X0-1,Y1)-(X0-1,Y0-1)-(X1+1,Y0-1),%10
1920 CONNECT (X0,Y1)-(X1,Y1)-(X1,Y0),0
1930 CONNECT (X0-1,Y1+1)-(X1+1,Y1+1)-(X1+1,Y0-1),0
1940 X0=X0+30 :X1=X0+140 :Y0=Y0-14 :Y1=Y0+24
1950 LINE (X0,Y0)-(X1,Y1),PSET,%9,BF
1960 CONNECT (X0,Y1)-(X0,Y0)-(X1,Y0),%10
1970 CONNECT (X0-1,Y1-12)-(X0-1,Y0+1)-(X1+1,Y0+1),%10
1980 CONNECT (X0,Y1)-(X1,Y1)-(X1,Y0+1),0
1990 CONNECT (X1+1,Y1-12)-(X1+1,Y0+1),0
2000 RETURN
2010 :
2020 *WIND1
2030 X0=50 :Y0=82 :X1=350 :Y1=450 :GOSUB *ウインド
2040 COLOR 4 :LOCATE 13,3 :PRINT AW1(0)
2050 FOR I=1 TO W1C
2060 X0=60 :Y0=93+I*24 :X1=190 :Y1=90+(I+1)*24
2070 CONNECT (X0,Y1)-(X0,Y0)-(X1,Y0),%10
2080 CONNECT (X0,Y1)-(X1,Y1)-(X1,Y0),0
2090 COLOR 6 :LOCATE 9,4+I :PRINT AW1(I);
2100 IF SW1(I)<0 THEN LOCATE 27,4+I :PRINT AW11(I);
2110 IF SW1(I)=-2 THEN PRINT ":"
2120 IF SW1(I)>=0 THEN LOCATE 25,4+I :PRINT " する しない"
2130 GOSUB *SW1
2140 NEXT
2150 RETURN
2160 :
2170 *SW1
2180 IF SW1(I)>=0 THEN 2270
2190 IF SW1(I)<-2 OR SW1(I)>1 THEN RETURN
2200 IX0=205 :IY0=93+I*24 :IY1=90+(I+1)*24
2210 IF SW1(I)=-1 THEN IX1=IX0+120
2220 IF SW1(I)=-2 THEN IX1=IX0+30
2230 IF SW1(11)=0 AND (I=5 OR I=6) THEN I0=9 :I1=9 ELSE I0=0 :I1=10
2240 CONNECT (IX0,IY1)-(IX0,IY0)-(IX1,IY0),%I0 :CONNECT (IX0,IY1)-(IX1,IY1)-(IX1,IY0),%I1
2250 RETURN
2260 :
2270 IX0=210 :IX1=274 :IY0=93+I*24 :IY1=90+(I+1)*24
2280 IF SW1(I) THEN 2340
2290 CONNECT (IX1,IY1)-(IX1,IY0)-(IX1+60,IY0),0
2300 CONNECT (IX1,IY1)-(IX1+60,IY1)-(IX1+60,IY0),%10
2310 CONNECT (IX0,IY1)-(IX0,IY0)-(IX0+57,IY0),%9
2320 CONNECT (IX0,IY1)-(IX0+57,IY1)-(IX0+57,IY0),%9
2330 RETURN
2340 :CONNECT (IX0,IY1)-(IX0,IY0)-(IX0+57,IY0),0
2350 CONNECT (IX0,IY1)-(IX0+57,IY1)-(IX0+57,IY0),%10
2360 CONNECT (IX1,IY1)-(IX1,IY0)-(IX1+60,IY0),%9
2370 CONNECT (IX1,IY1)-(IX1+60,IY1)-(IX1+60,IY0),%9
2380 RETURN
2390 :
2400 *設定DATA
2410 DATA "各 種 設 定" ,-3,""
2420 DATA "検索ドライブ" ,-2,"D"
2430 DATA " 〃 条件" ,-1,"*.*"
2440 DATA "出力先Drive名" ,-2,"D"
2450 DATA " 〃 File名" ,-1,"リスト.TXT"
2460 DATA "Copy先Drive名" ,-2,"A"
2470 DATA " 〃 DIR名" ,-1,"\BUCKUP\"
2480 DATA "1・分離表示" , 0,""
2490 DATA "2・フルパス表示", 1,""
2500 DATA "3・属性の表示" , 0,""
2510 DATA "4・DIRも表示" , 0,""
2520 DATA "5・COPYコマンド", 0,""
2530 DATA "6・DELコマンド" , 0,""
2540 DATA "7・特殊FILE検索", 0,""
2550 :
2560 *WINDO2
2570 I=0
2580 GOSUB *W2
2590 PRINT SPACE$(24)
2600 A=INPUT$(1)
2610 IF A="N" OR A="n" THEN *終了
2620 IF A=" " THEN RUN
2630 IF A="O" OR A="o" THEN *OMAKE
2640 IF A<>"Y" AND A<>"y" THEN 2600
2650 RETURN
2660 :
2670 *WIND2
2680 I=NO
2690 GOSUB *W2
2700 PRINT "<'ESCキー'で実行・取消>"
2710 RETURN
2720 :
2730 *W2
2740 COLOR 7
2750 A=AH(I)+SPACE$(40)
2760 FOR I0=1 TO 4
2770 LOCATE 52,4+I0
2780 PRINT MID$(A,I0*22-21,22)
2790 NEXT
2800 COLOR 5 :LOCATE 51,9
2810 RETURN
2820 :
2830 *HDATA
2840 DATA "Y ・・・・ 検索を開始するN ・・・・ 中止する SPC・・・・ 設定をし直す O ・・・・ おまけ"
2850 DATA "検索先のドライブ名を←→もしくはA~Qキーで選んでください。"
2860 DATA "検索条件をワイルドカード等で指定してください。*.*で全てのリストがでます。"
2870 DATA "リスト出力先のドライブ名を←→もしくはA~Qキーで選んでください。"
2880 DATA "リストのファイル名を入力して下さい。カレントディレクトリにセーブします。"
2890 DATA "COPYコマンド時のCOPY先ドライブ名を←→もしくはA~Qキーで選んでください。"
2900 DATA "COPY時のCOPY先ディレクトリを入力してください。例(\BUCKUP\) (\)等DIR の作成はしない。"
2910 DATA "パスとファイル名を分離する。プログラム中で使用する時便利。他の条件より最優先する。"
2920 DATA "ファイル名をフルパス付きでリストする。[しない]だとファイル名のみの出力。"
2930 DATA "リストに属性を付ける。[advshr]の有無がわかる。詳しくは何かの本を見てください。"
2940 DATA "リストにサブディレクトリ名も表示する。DISK内の構造を知るのに便利...かも?"
2950 DATA "COPYコマンドを付けてBAT FILEにする。COPY先は同ディレクトリ内なので同FILE名は消される。"
2960 DATA "DEL コマンドを付ける。6・も指定するとCOPY後DEL するBAT FILEを作成する。"
2970 DATA "特殊ファイル(隠し・システム)も検索の対象にするかどうか。リードオンリーは含まない。"
2980 :
2990 DATA "<只今、実行中です!>CDだと10分以上掛かることがあります。しばらくお待ち下さい。"
3000 DATA "<終了いたしました。>何かキーを押すとプログラムを終了いたします。 R=再実行"
3010 :
3020 *入力
3030 NO=1 :ONO=10
3040 *IN0
3050 IF NO<1 THEN NO=W1C
3060 IF NO>W1C THEN NO=1
3070 GOSUB *WIND2
3080 LOCATE 9,4+ONO :COLOR 6 :PRINT AW1(ONO)
3090 LOCATE 9,4+NO :COLOR 5 :PRINT AW1(NO)
3100 ONO=NO
3110 *IN1
3120 A=INPUT$(1)
3130 IF A=CHR$(27) THEN RETURN
3140 IF A=" " THEN CLOSE:END
3150 IF A=CHR$(&H1F) THEN NO=NO+1 :GOTO *IN0
3160 IF A=CHR$(&H1E) THEN NO=NO-1 :GOTO *IN0
3170 IF SW1(NO)=-2 THEN *IN3 '##ドライブ名
3180 IF SW1(NO)=-1 THEN *IN4 '##ファイル名
3190 IF SW1(NO)>=0 THEN *IN2 '##設定ON-OFF
3200 GOTO *IN0
3210 :
3220 *IN2
3230 IF A<>CHR$(&H1C) AND A<>CHR$(&H1D) THEN *IN1
3240 SW1(NO)=-(SW1(NO)=0)
3250 IF SW1(7) THEN SW1(8)=1 :SW1(9)=0 :SW1(10)=0 :SW1(11)=0 :SW1(12)=0
3260 IF SW1(11) OR SW1(12) THEN SW1(8)=1 :SW1(9)=0 :SW1(10)=0
3270 FOR I=1 TO W1C :GOSUB *SW1 :NEXT :GOTO *IN1
3280 *IN3
3290 IF A<="S" AND A>="A" THEN A0=A :GOTO 3340
3300 IF A<="s" AND A>="a" THEN A0=CHR$(ASC(A)-&H20) :GOTO 3340
3310 A0=CHR$(ASC(AW11(NO))-(A=CHR$(&H1C))+(A=CHR$(&H1D)))
3320 IF A0<"A" THEN A0="Q"
3330 IF A0>"S" THEN A0="A"
3340 AW11(NO)=A0 :COLOR 6 :LOCATE 27,4+NO :PRINT AW11(NO);":"
3350 GOTO *IN1
3360 *IN4
3370 IF A<>CHR$(13) AND A<>CHR$(&H1C) THEN *IN1
3380 COLOR 7 :LOCATE 27,4+NO
3390 LINE INPUT "",A0
3400 IF A0="" THEN *IN1
3410 COLOR 6 :LOCATE 27,4+NO
3420 IF LEN(A0)>12 THEN A0=LEFT$(A0,12)
3430 AW11(NO)=A0 :PRINT A0+SPACE$(13)
3440 GOTO *IN1
3450 :
3460 *入力変換
3470 DRIVE$=AW11(1)+":" :'##検索DRIVE
3480 WILD$=AW11(2) :'##検索条件
3490 IF AW11(3)="S" THEN AW11(3)="SCRN"
3500 OF_N$=AW11(3)+":\"+AW11(4) :'##出力FAIL名
3510 CP_N$=AW11(5)+":"+AW11(6) :'##COPY先名
3520 FRG1=SW1(7) :'##分離表示
3530 FRG2=SW1(8) :'##フルパスの表示
3540 FRG3=SW1(9) :'##属性の表示
3550 FRG4=SW1(10) :'##リストにDIRも表示する
3560 FRG5=SW1(11) :'##COPYコマンドの付加
3570 FRG6=SW1(12) :'##DELコマンドの付加
3580 FRG7=SW1(13) :'##特殊ファイルの検索
3590 :
3600 IF FRG1 THEN FRG2=1 :FRG3=0 :FRG4=0 :FRG5=0 :FRG6=0
3610 IF FRG5 OR FRG6 THEN FRG2=1 :FRG3=0 :FRG4=0
3620 RETURN
3630 :
3640 '-----
3650 *MAIN
3660 COLOR 7
3670 SHELL DRIVE$
3680 SHELL "CHDIR \"
3690 GOSUB *DIR_CALL
3700 LOCATE 65,13 :PRINT FCT
3710 LOCATE 65,14 :PRINT FCT1
3720 LOCATE 65,15 :PRINT DIRC
3730 LOCATE 65,16 :PRINT FCT2
3740 IF C_N(DIR)=0 THEN 3800
3750 '##DIRが有れば子DIRに移る
3760 SHELL "CHDIR "+F_N$(DIR,C_N(DIR))
3770 DIR=DIR+1 :LOCATE 63+DIR,18 :PRINT "* "
3780 GOTO 3690
3790 '##DIRが無ければ親に移る
3800 DIR=DIR-1 :LOCATE 63+DIR,18 :PRINT "* "
3810 IF DIR<0 THEN 3860
3820 C_N(DIR)=C_N(DIR)-1
3830 SHELL "CHDIR .."
3840 IF C_N(DIR)=0 THEN 3800
3850 GOTO 3760
3860 LOCATE 62,18 :PRINT " 終了"
3870 RETURN
3880 :
3890 '----1ディレクトリ内の検索----
3900 *DIR_CALL
3910 :
3920 PASS$="\" :I=0
3930 IF I<DIR THEN PASS$=PASS$+F_N$(I,C_N(I))+"\" :I=I+1 :GOTO 3930
3940 S=0:F$=FNFILE$(WILD$)
3950 LOCATE 62,17 :PRINT "● ―"
3960 GOSUB *M_CALL1
3970 GOSUB *M_CALL2
3980 S=1:F$=FNFILE$("*.*")
3990 DCT=0 :'##ディレクトリカウンタ
4000 LOCATE 62,17 :PRINT "― ●"
4010 GOSUB *M_CALL1
4020 GOSUB *M_CALL2
4030 C_N(DIR)=DCT
4040 LOCATE 62,17 :PRINT "― ― "
4050 RETURN
4060 :
4070 '----マシン語のコール----
4080 *M_CALL1
4090 FLAG&=1
4100 CALLM MC1&,VARPTR(F$),VARPTR(FLAG&)
4110 IF FLAG&<>0 THEN GOSUB *F_OUT
4120 RETURN
4130 :
4140 *M_CALL2
4150 CALLM MC2&,VARPTR(F$),VARPTR(FLAG&)
4160 IF FLAG&<>0 THEN GOSUB *F_OUT :GOTO *M_CALL2
4170 RETURN
4180 :
4190 '----データの分離----
4200 *F_OUT
4210 A0=RIGHT$(F$,6) :'##情報
4220 A=LEFT$(F$,8) :'##ファイル名
4230 :I=1
4240 :IF MID$(A,I,1)<>" " AND I<=8 THEN I=I+1 :GOTO 4240
4250 :A1=LEFT$(A,I-1)
4260 A=MID$(F$,10,3) :'##拡張子
4270 :IF A=" " THEN A2="" :GOTO 4310
4280 :I=1
4290 :IF MID$(A,I,1)<>" " AND I<=3 THEN I=I+1 :GOTO 4290
4300 :A2="."+LEFT$(A,I-1)
4310 IF A1="." OR A1=".." THEN RETURN
4320 IF MID$(A0,3,1)="v" THEN RETURN
4330 A3=A1+A2 :'##新F名
4340 :
4350 IF S THEN *FSD ELSE *FNAME
4360 :
4370 '----ディレクトリの検索----
4380 *FSD
4390 IF MID$(A0,2,1)<>"d" THEN FCT1=FCT1+1:RETURN :'##総F数
4400 DIRC=DIRC+1 :'##総DIR数
4410 DCT=DCT+1
4420 F_N$(DIR,DCT)=A1
4430 AP=""
4440 IF FRG3 THEN AP=AP+A0+" " :'##属性表示
4450 IF FRG2 THEN AP=AP+PASS$ :'##フルパス表示
4460 IF FRG4 THEN PRINT #1,AP+A3
4470 RETURN
4480 :
4490 '----ファイル名の検索----
4500 *FNAME
4510 IF MID$(A0,2,1)="d" THEN RETURN
4520 IF MID$(A0,4,1)="s" OR MID$(A0,5,1)="h" THEN FCT2=FCT2+1 :IF FRG7=0 THEN RETURN
4530 FCT=FCT+1 :'##該当F数
4540 AP="" :A4="" :A5=""
4550 IF FRG3 THEN AP=AP+A0+" " :'##属性表示
4560 IF FRG2 THEN AP=AP+PASS$ :'##フルパス表示
4570 IF FRG5 THEN A4="COPY "+DRIVE$ :A5=" "+CP_N$ :'##COPYコマンドの付加
4580 :
4590 IF FRG1 THEN PRINT #1,AP :PRINT #1,A3 :RETURN
4600 IF FRG6=0 OR (FRG5*FRG6) THEN PRINT #1,A4+AP+A3+A5
4610 IF FRG6 THEN PRINT #1,"DEL "+DRIVE$+AP+A3
4620 RETURN
4630 :
4640 '------ E N D --------
4650 :
4660 *OMAKE
4670 KEY 5,"リスト.TXT"
4680 SCREEN@ 0 :CLS :COLOR 5
4690 PRINT "*** FILE NAME LISTER ***"
4700 PRINT "*** おまけ コーナー ***"
4710 PRINT "*** 1993/01/05 by 尋燐・ルナ ***"
4720 PRINT
4730 COLOR 7
4740 PRINT " 1 ・・・・・ フルパスリストにドライブ番号を付ける。"
4750 PRINT " 2 ・・・・・ TIFファイルを連続して見る。"
4760 PRINT " 3 ・・・・・ 注意事項"
4770 PRINT " 4 ・・・・・ メインプログラムに戻る。"
4780 PRINT
4790 PRINT " <どれを選択しますか?> "
4800 A=INPUT$(1)
4810 :IF A="1" THEN *ADD
4820 :IF A="2" THEN *TIF
4830 :IF A="3" THEN *注意
4840 :IF A="4" THEN RUN
4850 :GOTO 4800
4860 :
4870 *TIF
4880 PRINT :PRINT :PRINT :COLOR 5
4890 PRINT "*** 簡易TIFファイル表示 ***"
4900 PRINT "*** by 尋燐・ルナ ***"
4910 PRINT "注)SCREEN@ 0-3 以外の画面モードには対応してません。 "
4920 PRINT :COLOR 7
4930 LINE INPUT ">リストの名は(ドライブ番号からフルパスで)_ ";F$
4940 PRINT "-リストにドライブ番号が含まれている時はret.のみ-"
4950 INPUT ">表示画像ファイルの入っているドライブは_ ";AD
4960 IF LEN(AD)>0 THEN AD=LEFT$(AD,1)+":" ELSE AD=""
4970 DIM FF$(5000)
4980 MAX=1
4990 OPEN "I",#1,F$
5000 IF EOF(1)=0 THEN LINE INPUT #1,FF$(MAX) :MAX=MAX+1 :GOTO 5000
5010 CLOSE
5020 PRINT "ファイルは ";MAX;"ありました。"
5030 ON ERROR GOTO 5130
5040 S=0 :SCREEN@ 0 :CLS
5050 FOR I=1 TO MAX
5060 C=1
5070 LOAD@ AD+FF$(I)
5080 LOCATE 0,0 :PRINT I
5090 NEXT
5100 ON ERROR GOTO 0
5110 WAIT 200
5115 ERASE FF$
5120 GOTO *OMAKE
5130 '-err
5140 IF NOT(ERL=5070 AND ERR=112) THEN RESUME NEXT
5150 C=C+1 :LOCATE 0,0 :PRINT "ERR!"
5160 IF C=4 THEN RESUME NEXT
5170 S=S-1 :IF S=-1 THEN S=2
5180 IF S=0 THEN SCREEN@ 0
5190 IF S=1 THEN SCREEN@ 1
5200 IF S=2 THEN SCREEN@ 2
5210 RESUME
5220 :
5230 *ADD
5240 AZ="ZZZZZZZZ.ZZZ"
5250 PRINT :PRINT :PRINT :COLOR 5
5260 PRINT "*** ドライブ番号の付加 ***"
5270 PRINT "*** by 尋燐・ルナ ***"
5280 PRINT :COLOR 7
5290 LINE INPUT ">変更するリストのフルパスは、(ファイル名は省く)_ ";AP
5300 LINE INPUT "> ファイル名は、_ ";AF
5310 LINE INPUT ">付加するドライブ名は、_ ";AD
5320 AD=LEFT$(AD,1)+":"
5330 PRINT "...実行中!"
5340 PRINT "...古いファイル名の変更"
5350 NAME AP+AF AS AZ
5360 PRINT "...リストの書換え"
5370 PRINT ">";
5380 OPEN "I",#1,AP+AZ
5390 OPEN "O",#2,AP+AF
5400 LINE INPUT #1,A
5410 A=AD+A :PRINT ".";
5420 PRINT #2,A
5430 IF EOF(1)=0 THEN 5400
5440 CLOSE #2
5450 CLOSE #1
5460 KILL AP+AZ
5470 PRINT :PRINT "...終了しました"
5480 WAIT 100
5490 GOTO *OMAKE
5500 :
5510 *注意
5520 CLS :COLOR 5
5530 PRINT "*** FILE NAME LISTER ***"
5540 PRINT "*** 注 意 事 項 ***"
5550 PRINT "*** by 尋燐・ルナ ***"
5560 PRINT :COLOR 7
5570 PRINT "<この度このプログラムを使用していただき誠に有り難うございます。"
5580 PRINT " 以下に簡単な使用上の注意をあげておきます。>"
5590 PRINT
5600 PRINT "・当プログラムは恐ろしいほどエラーチェックをしておりません。"
5610 PRINT " (ドライブの確認、ファイル名、ワイルドカード等)"
5620 PRINT " サイドワーク(ファイル操作)等で確認してください。"
5630 PRINT "・ESCキーを押したかとの選択は仮名、全角になっているとそのまま終了してし"
5640 PRINT " しまいます。英大、英小で選択してください。"
5650 PRINT "・CDの検索には時間が掛かります。特にGNUは超最悪です。23736ファイル"
5660 PRINT " 約30分かかります。他は大体10分位.....かな?"
5670 PRINT "・裏技としてリスト出力先にSを指定するとスクリーンに表示されます。"
5680 PRINT " 但しテスト用なので画面が乱れます。"
5690 PRINT "・裏技2としてリスト出力をルートディレクトリでなくサブDIRに出来ます。"
5700 PRINT " ファイル名の欄にフルパスで記入してください。はみ出すけど.."
5710 A=INPUT$(1)
5720 GOTO *OMAKE
5730 :
5740 '--------------- e n d --------------